Алгоритм переименования страниц

zhuravsky

Прошу помощи по такому вопросу: у меня многостраничный документ (111 страниц) и мне необходимо, чтобы в конце работы все страницы шли по порядку (Page-1, Page-2, ... Page-111). При этом в процессе работы новые страницы могут вставляться не только в конец документа, но и в середину, т.е. порядок следования страниц нарушается. Сами имена страниц назначаются Визио по умолчанию и не меняются, т.е. по шаблону "Page-" & номер_очередной_страницы.
В какой-то момент у меня получилось так, что стандартная команда Визио Re-order Pages стала выдавать ошибку (в моём случае "Page-103 already in use..."), похоже, что сам внутренний алгоритм некорректен в моей версии. Я написал макрос для переименования страниц, но неожиданно оказалось, что сам процесс переименования очень медлительный и при моём количестве страниц занимает много времени. В общем, надо как-то оптимизировать код, а мне хороший алгоритм в голову что-то не приходит. Вот макрос:

Код:

Public Sub Reorder_Page_Names()
    Dim vsoPage As Visio.Page
    Dim vsoTestPage As Visio.Page
    Dim sPageName As String
    Dim Cnt As Long
    Dim I As Long
    Dim PageIndex As Long
    
    'On Error Resume Next
    Debug.Print "Start"
    For I = 1 To ActiveDocument.Pages.Count
        Set vsoPage = ActiveDocument.Pages(I)
        If Not vsoPage.Background Then
            '
            Debug.Print vsoPage.Name
            '
            PageIndex = vsoPage.Index
            sPageName = "Page-" & Format(PageIndex, "#")
            If StrComp(sPageName, vsoPage.Name, vbTextCompare) <> 0 Then
                Set vsoTestPage = Nothing
                On Error Resume Next
                Set vsoTestPage = ActiveDocument.Pages(sPageName)
                On Error GoTo 0
                If vsoTestPage Is Nothing Then ' can rename
                    vsoPage.Name = sPageName
                Else ' can not rename
                    'Debug.Print "Can't rename " & vsoPage.Name & " -> " & sPageName
                    vsoTestPage.Name = "Page__" & Format(PageIndex, "#")
                    vsoPage.Name = sPageName
                End If
            End If
        End If
        DoEvents
    Next
    Debug.Print "Finish"
End Sub

Surrogate

zhuravsky писал(а):

стандартная команда Визио Re-order Pages стала выдавать ошибку (в моём случае "Page-103 already in use..."), похоже, что сам внутренний алгоритм некорректен в моей версии

Подозреваю тут проблема локальных и универсальных имен!

zhuravsky писал(а):

что сам процесс переименования очень медлительный и при моём количестве страниц занимает много времени

Странно это!

zhuravsky в сообщении #18682 писал(а):

Я пока пробовал цикл по всем страницам с анализом имени шейпа и цикл по страницам с CreateSelection by master. Вроде, по времени разницы особо не видно...

У меня в этих случаях разницу видно, а с переименованием страниц была раз задача переименования 140 страниц. минуты за 3 управился. там был очень тяжелый файл, много больших скринов или чёрточек импортированных из AutoCAD

zhuravsky писал(а):

надо как-то оптимизировать код, а мне хороший алгоритм в голову что-то не приходит.

Я сегодня далеко от компа с Visio. Но моя пара советов
1. Добавить код по событию добавления страницы, чтоб переименование происходило сразу

Код:

Private Sub Document_PageAdded(ByVal Page As IVPage)

2. Проводить перебор страниц не с начала, а с конца
For I = 1 To ActiveDocument.Pages.Count
до вновь добавленной

Код:

Private Sub Document_PageAdded(ByVal Page As IVPage)
Dim RSP As Integer ' rename start position
RSP = Page.Index
…
For i = ActiveDocument.Pages.Count To RSP Step -1 ' страницы до вставленной не трогаем !
…
Next

Surrogate

Surrogate писал(а):

Подозреваю тут проблема локальных и универсальных имен!

Не так! Новой странице по умолчанию добавляется максимальный индекс, начинаете пересортицу и в какой-то момент встречается уже задействованное имя. Тут не помогает перебор страниц в обратном порядке, т.е. крайняя справа страница должна иметь максимальный номер. А у вас последняя добавленная имеет такой же. Новую страницу переименовывать сначала в tmp, а после перебора страниц она получит свое порядковое имя :mrgreen:

Код:

Private Sub Document_PageAdded(ByVal Page As IVPage)
Dim RSP As Integer ' rename start position
RSP = Page.Index
Page.Name = "temp"
For i = ActiveDocument.Pages.Count To RSP Step -1
Set pg = ActiveDocument.Pages(i)
pg.Name = "Page-" & i
Next
End Sub

Tumanov

Цитата:

что сам процесс переименования очень медлительный и при моём количестве страниц занимает много времени
Странно это!

А почему странно-то? Ведь в формулах шейп-листа могут быть ссылки на другой лист. Значит Visio обязан проверить все формулы на предмет - не встречается ли в них старое имя страницы и, если встречается, заменить его на новое. Если шейпов много, то это длинная проверка.
Похоже, время должно зависеть не только от количества страниц, но и от количества шейпов на них.

Tumanov

Цитата:

Новую страницу переименовывать сначала в tmp

Немного про имена.
Межстраничные ссылки используют универсальное имя страницы. А внизу листа пользователь наблюдает локальное имя. И переименовывает только локальноее имя. Во всех последующих случаях кроме первого. А вот первое переименование действует сразу и на локальное, и на универсальное. Вот такая каша...
Получается, если один раз зафиксировать универсальное имя, то потом с локальным можно делать что угодно: добавлять буковки, убирать их и т.д. То есть Page-1 можно заменить на Page-1tmp, а вторым проходом Page-1tmp заменить на Page-5. Так можно обходить ошибки типа "страница уже существует". Хотя, на скорость это не повлияет

zhuravsky

Пришёл в итоге вот к такому алгоритму:

Код:

Public Sub Reorder_Page_Names()
    Dim vsoPage As Visio.Page
    Dim vsoTestPage As Visio.Page
    Dim sPageName As String
    Dim I As Long
    Dim J As Long
    Dim Count As Long
    Dim timeStart As Single
    Dim timeDuration As Long
    Dim lngUndoScopeID As Long
    
    On Error Resume Next
    lngUndoScopeID = Application.BeginUndoScope("Pages rename")
    Debug.Print "Start"
    timeStart = Timer
    I = 1
    Count = ActiveDocument.Pages.Count
    sPageName = "Page-" & Format(I, "#")
    Set vsoPage = ActiveDocument.Pages(I)
    While StrComp(ActiveDocument.Pages(I).Name, "Page-" & Format(I, "#"), vbTextCompare) = 0
        I = I + 1
    Wend
    '
    While ActiveDocument.Pages(Count).Background
        Count = Count - 1
    Wend
    '
    While StrComp(ActiveDocument.Pages(Count).Name, "Page-" & Format(Count, "#"), vbTextCompare) = 0
        Count = Count - 1
    Wend
    For J = Count To I Step -1
        sPageName = "Page-" & Format(J, "#")
        Debug.Print ActiveDocument.Pages(J); "  --->  "; "Page-" & Format(J, "#"), "try if "; sPageName; " exists... ";
        Set vsoTestPage = Nothing
        Set vsoTestPage = ActiveDocument.Pages(sPageName)
        If Not (vsoTestPage Is Nothing) Then
            vsoTestPage.Name = "_Temp_" & J
            'vsoTestPage.NameU = "_Temp_" & J
            Debug.Print "Exists, renaming to "; "_Temp_" & J
        Else
            Debug.Print "does not exist."
        End If
        ActiveDocument.Pages(J).Name = sPageName
        'ActiveDocument.Pages(J).NameU = sPageName
        '
        DoEvents
    Next J
    '
    Application.EndUndoScope lngUndoScopeID, True
    timeDuration = Round(Timer - timeStart, 0)
    Debug.Print timeDuration; " seconds elapsed."
    Debug.Print "Finish"
End Sub

gtfox

Tumanov писал(а):

Получается, если один раз зафиксировать универсальное имя, то потом с локальным можно делать что угодно: добавлять буковки, убирать их и т.д.

Делал также

Первое переименование Name фиксирует NameU, и пользователь уже не может навредить.

nbelyh

Что-то я не понял в чем смысл двойного переименования? NameU фиксируется, как только появляется хоть какое-то имя:

Код:

Set p = ActiveDocument.Pages.Add

Debug.Print p.Name, p.NameU         -> Page2, Page-2  (нет имени)

p.Name = "A"
Debug.Print p.Name, p.NameU         -> A, A (имя появилось, инициализировались Name и NameU)

p.Name = "B"
Debug.Print p.Name, p.NameU         -> B A  (поменялось только Name)

p.Name = "C"
Debug.Print p.Name, p.NameU         -> C, A (снова поменялось только Name)

Set p = ActiveDocument.Pages.Add 

Debug.Print p.Name, p.NameU           -> Page-3, Page-3 (новая страница)

p.Name = "A"
Debug.Print p.Name, p.NameU           -> ОШИБКА, "А" уже существует, хотя его не видно в интерфейсе (для второй страницы показывается "C")

Для того чтобы исправить исходный код, скорее всего достаточно было просто изменять оба имени (Name и NameU).
К сожалению для этого надо было знать о том что существует такая "подлянка" как NameU.

vsoPage.Name = sPageName
vsoPage.NameU = sPageName

Но это раньше. Теперь документ там наверняка превратился в кашу.
Так что сначала Name и NameU надо синхронизовать, т.е. чтобы они совпадали.

Tumanov

Цитата:

Что-то я не понял в чем смысл двойного переименования?

Да это просто прием, чтобы избежать ошибки "имя уже существует". Типа, сначала перейти на другую систему нумерации, потом вернуться обратно, но уже с новыми именами. Конечно, это не единственный вариант.

Форум пользователей Visio

Правила форума

Алгоритм переименования страниц

Кто сейчас на конференции